COMMENT ⊗   VALID 00003 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	BEGIN "GEAR"
C00006 00003	
C00007 ENDMK
C⊗;
BEGIN "GEAR"
REAL NP,NG,PD,HK,HT,PHI,SIG;
REAL DP,DG,GAMG,GAMP,A0,PP,A0P,A0G,B0P,B0G,C,DELP,DELG,GAM0P,GAM0G,GAMRP,GAMRG,
	D0P,D0G,X0P,X0G,F;

PROCEDURE ASK(STRING NAME; REFERENCE REAL VAL);
   BEGIN
   STRING S; INTEGER FOO;
   OUTSTR(NAME&": ");
   VAL←REALSCAN(S←INCHWL,FOO);
   END;

PROCEDURE PRT(STRING NAME; REAL VAL);
   OUTSTR(NAME&" "&CVF(VAL)&'15&'12);

REAL PROCEDURE D(REAL ANG); RETURN(180*ANG/3.14159265);

ASK("PINION TEETH",NP);
ASK("GEAR TEETH",NG);
ASK("DIAMETRAL PITCH",PD);
HK←2/PD;
HT←2.188/PD+0.002;
ASK("PRESSURE ANGLE",PHI);  PHI←PHI*3.14159265/180;
ASK("SHAFT ANGLE",SIG);  SIG←SIG*3.14159265/180;

DP←NP/PD;			DG←NG/PD;
GAMP←ATAN(SIN(SIG)/(NG/NP+COS(SIG)));
GAMG←SIG-GAMP;
A0←DG/(2*SIN(GAMG));
PP←3.14159265/PD;
A0G←0.540/PD+0.460/(PD*(NG/NP)↑2);
A0P←HK-A0G;
B0P←HT-A0P;			B0G←HT-A0G;
C←0.188/PD+0.002;
DELP←ATAN(B0P/A0);		DELG←ATAN(B0G/A0);
GAM0P←GAMP+DELG;		GAM0G←GAMG+DELP;
GAMRP←GAMP-DELP;		GAMRG←GAMG-DELG;
D0P←DP+2*A0P*COS(GAMP);		D0G←DG+2*A0G*COS(GAMG);
X0P←A0*COS(GAMP)-A0P*SIN(GAMP);	X0G←A0*COS(GAMG)-A0G*SIN(GAMG);

F←10/PD MIN A0/5;

PRT("WORKING DEPTH-HK",HK);
PRT("WHOLE DEPTH-HT",HT);
PRT("PINION PITCH DIA-DP",DP);
PRT("GEAR PITCH DIA-DG",DG);
PRT("MAX RECOMMENDED FACE WIDTH-F",F);
PRT("OUTER CONE DISTANCE-A0",A0);
PRT("CIRCULAR PITCH-PP",PP);
PRT("PINION ADDENDUM-A0P",A0P);
PRT("GEAR ADDENDUM-A0G",A0G);
PRT("PINION DEDENDUM-B0P",B0P);
PRT("GEAR DEDENDUM-B0G",B0G);
PRT("CLEARANCE-C",C);
PRT("PINION PITCH ANGLE-GAMP",D(GAMP));
PRT("GEAR PITCH ANGLE-GAMG",D(GAMG));
PRT("PINION DEDENDUM ANGLE-DELP",D(DELP));
PRT("GEAR DEDUNDUM ANGLE-DELG",D(DELG));
PRT("FACE ANGLE OF PINION BLANK-GAM0P",D(GAM0P));
PRT("FACE ANGLE OF GEAR BLANK-GAM0G",D(GAM0G));
PRT("ROOT ANGLE OF PINION-GAMRP",D(GAMRP));
PRT("ROOT ANGLE OF GEAR BLANK-GAMRG",D(GAMRG));
PRT("PINION OUTSIDE DIA-D0P",D0P);
PRT("GEAR OUTSIDE DIA-D0G",D0G);
PRT("PINION PITCH APEX TO CROWN-X0P",X0P);
PRT("GEAR PITCH APEX TO CROWN-X0G",X0G);

END;