COMMENT ⊗   VALID 00034 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00005 00002	Network routines, intended to be .INSRT'ed
C00011 00003	 INTINR INTINS INTIMS INTINP RFCS RFCR CLSS CLSR SIU CCS SYS NLA ILB IDD GMM IOIMPM IODERR IODTER IOBKTL IODEND ERRBTS WINBTS ICP NET DAT NT$NUM NE%UNT NE%STR NN%IP NW%ARP NW%MIL NW%SI NW%SU
C00015 00004	 NWKDBG HSTADR HSTTOP HDBPTR DHSTST CONBLK CONSTS CONLSK CONWAT CONBYT ICPSKT CONFSK HOST CONHST LSNBLK LSNSTS LSNSKT LSNWAT LSNBYT LSNFSK LSNHST OPNBLK NETDEV
C00018 00005	 WATBLK WATSTS WATSKT INRBLK INRSTS INRSKT INSBLK INSSTS INSSKT ABTBLK ABTSTS WHYWHY NTIBF NTOBF DTIBF DTOBF RMKBLK RMKSTS RMKDAT FSOCKT LSOCKT
C00020 00006	 CONECT .CONEC
C00023 00007	 LISTEN .LISTE
C00026 00008	 DATI .DATI .DATI1
C00028 00009	 DATO .DATO .DATO1
C00030 00010	 NETICH NETICW NTICH2 NTICH4 NTICH3
C00033 00011	 NETOCH .NETOC
C00034 00012	 NETSND .NETSN NETOER
C00035 00013	 DATICH DATICW DTICH2 DTICH3 DTICH1 DTIC1A
C00039 00014	 DATOCH .DATOC
C00040 00015	 DATSND .DATSN DATOER
C00042 00016	 CLOSER CLSDAT
C00043 00017	 NETINR NETINS ABORT
C00044 00018	 MTPERR MTPER1 MTPE1A MERTAB MERLEN
C00048 00019	 NIOERR
C00049 00020	 HSTDED
C00052 00021	 HSTDE2
C00054 00022	 HSTSID HSTFN1 HSTVRS HSTDIR HSTDEV HSTWHO HSTDAT HSTTIM NAMPTR SITPTR NETPTR NTNPTR HDRLEN NETNUM NTLNAM NTRTAB NETLEN ADDADR ADLSIT ADRCDR ADLXXX ADRSVC SVLCNT SVRCDR SVLFLG SVRNAM SVCARG ADDLEN STLNAM STRADR STLSYS STRMCH STLFLG STFSRV STFGWY SITLEN NMLSIT NMRNAM NAMLEN NNLNET NNRNAM NTNLEN HSTFIL HSTPPN
C00065 00023	 MAPHST
C00067 00024	 UNMHST
C00068 00025	 HSTNUM HSTNUS HSTNU1 HSTNU2
C00072 00026	 HSTNAM CNTCHR HSTNAB HSTNB1 HSTNB2 HSTNB3 HSTNB4 HSTNB5 HSTUNK HSTUN1
C00076 00027	 SEARCH SRCNXW SRCWIN SRCLUZ SRCDUN GOTNAM AMBNAM GETHDB
C00080 00028	 HSTNXA
C00081 00029	 SVCCHK SVCCH1 SVCCH2 SVCCH3
C00083 00030	 SETANM SETA00 SETAN1 SETAN0 SETAN2 SETAN4 SETAN5 SETAN9 SETAN6 SETAN7 SETAN8
C00087 00031	 HNUMST HNUMS2 HNUMS4 HNUMS5 HNUMSD HNUMSO HNUMS6
C00090 00032	 OURNAM OURNA1
C00092 00033	 TTYSTR TTYST1 TTST1A TTYST2 TTST2A TTYST3 TTYST4 TTST4A TTYST5 TTST5A TTST5B TTYST6 TTYST9
C00097 00034	 CPOPJ2 CPOPJ1 CPOPJ WARNIN LUZBIG ..NLIT
C00098 ENDMK
C⊗;
SUBTTL Network routines, intended to be .INSRT'ed

; Mark Crispin, SU-AI, April 1978

;  This is a library of ARPAnet hacking routines.  Each routine describes its
; calling sequence and what AC's it smashes.  A pushdown stack is expected in 17.
;  I/O channel 0 is smashed, I/O channel 1 (NET) is used as the general TELNET
; connection channel, and I/O channel 2 (DAT) is used for data I/O.
;  Bugs → MRC.

;  This package can also be used with the Ethernet as well, but data connections
; are not implemented. Also, Ethernet does not have equivalent to INTINR, and
; simply sends an INTINS. Host down messages are bogus. (TVR/Dec81)

;  Modified for ARPAnet IP/TCP in April 1983.  Major change is the elimination
; of ICP for ARPAnet connections.  Bugs → ME and JJW.

;  Changed host table to use HOSTS3 format (JJW - June 83).

;  This is the MIDAS version which lives in NETWRK.MID[S,NET].  The FAIL version
; lives in NETWRK.FAI[S,NET].

; Assembly switches

IF1,[
IFDEF FTHST3,[
PRINTX/Please remove the FTHST3 switch and non-HOSTS3 code from this program.
All NETWRK-reading programs must now use HOSTS3 host numbers.
/];IFDEF FTHST3
];IF1
IFNDEF SVRRTS,SVRRTS==0			; ≠ 0 → server (not user) routines
IFNDEF DATRTS,DATRTS==0			; ≠ 0 → data channel routines
IFNDEF MRKCHR,MRKCHR==0			; ≠ 0 → pass BSP mark bytes as characters
IFNDEF ERRHAN,ERRHAN==0			; ≠ 0 → automagic error reporting in NIORTS
IFNDEF ERRINS,ERRINS==EXIT		; (iff ERRHAN≠0) what to do after an error
IFNDEF HSTSIX,HSTSIX==0			; ≠ 0 → sixbit alias name hacking
IFNDEF TTYSTS,TTYSTS==0			; ≠ 0 → code to get TTY location string

IFNDEF NIORTS,NIORTS==SVRRTS\DATRTS\ERRHAN ; ≠ 0 → network I/O routines

IFNDEF ERRTNS,ERRTNS==ERRHAN		; ≠ 0 → error reporting routines

IFNDEF HSTTAB,HSTTAB==HSTSIX		; ≠ 0 → host table routines

IFE NIORTS\ERRTNS\HSTTAB,.FATAL No NETWRK routines selected
IFE NIORTS,IFN SVRRTS\DATRTS\ERRHAN,.FATAL NIORTS Illegal switch setting
IFE ERRTNS,IFN ERRHAN,.FATAL ERRHAN Illegal switch setting
IFE HSTTAB,IFN HSTSIX,.FATAL HSTTAB Illegal switch setting
IFE NIORTS,IFN MRKCHR,.FATAL MRKCHR Illegal switch setting

; Macro definitions

DEFINE TMSG STRING
 OUTSTR [ASCIZ\!STRING!\]
TERMIN

;  FATAL errors type an exclamation point and halt.  WARNings type a question
; mark and continue.

DEFINE FATAL STRING
 PUSHJ 17,[OUTSTR [ASCIZ\!STRING!?\] ? JRST LUZBIG]
TERMIN

DEFINE WARN STRING
 PUSHJ 17,[OUTSTR [ASCIZ\!STRING!!\] ? JRST WARNIN]
TERMIN

; Timeouts for various flavors of connection

IFNDEF CNTIMO,CNTIMO==010000170500	; connect ICP
IFNDEF LSTIMO,LSTIMO==011212360000	; listen ICP
IFNDEF TNTIMO,TNTIMO==011700050000	; TELNET socket
IFNDEF DATIMO,DATIMO==022400070000	; data socket

;Macro to zero all but network number in a word.  Placed outside .BEGIN so
;programs .INSRTing this file can use it.

DEFINE GETNET AC,(ADDR)
IFNB [ADDR] MOVE AC,ADDR
	TLNN AC,(17←32.)	; Check for non-Internet type addrs
	 TLNN AC,(1←31.)	;  Internet address, see if class A net
	  TDZA AC,[77,,-1]	;   Unternet or class A, zap low 3 octets
	TLNN AC,(1←30.)		; Class B or C, see which.
	 TRZA AC,177777		;  Class B network, zap low 2 octets
	  TRZ AC,377		;   Class C net, only zap 1 low octet
TERMIN
;⊗ INTINR INTINS INTIMS INTINP RFCS RFCR CLSS CLSR SIU CCS SYS NLA ILB IDD GMM IOIMPM IODERR IODTER IOBKTL IODEND ERRBTS WINBTS ICP NET DAT NT$NUM NE%UNT NE%STR NN%IP NW%ARP NW%MIL NW%SI NW%SU

; System bits and bytes

.BEGIN NETWRK

; Interrupt condition bits

.U"INTINR==000100,,			; IMP INR
.U"INTINS==000040,,			; IMP INS
.U"INTIMS==000020,,			; IMP status change
.U"INTINP==000010,,			; IMP input waiting

; Network socket status flags

.U"RFCS==  200000,,			; RFC sent
.U"RFCR==  100000,,			; RFC received
.U"CLSS==  040000,,			; CLS sent
.U"CLSR==  020000,,			; CLS received

; Network status word error codes

.U"SIU==01				; socket in use
.U"CCS==02				; can't change socket numbers
.U"SYS==03				; horrible system error
.U"NLA==04				; no links available
.U"ILB==05				; illegal byte size
.U"IDD==06				; IMP dead
.U"GMM==07				; Gender mismatch

; I/O status word error bits

.U"IOIMPM==400000			; improper mode
.U"IODERR==200000			; hard device error
.U"IODTER==100000			; soft device error
.U"IOBKTL==040000			; block number out of bounds
.U"IODEND==020000			; end of file
.U"HDEAD== 002000			; host or destination IMP dead
.U"RSET==  000400			; host sent a RST
.U"TMO==   000200			; time out

ERRBTS==IOIMPM\IODERR\IODTER\IOBKTL\IODEND\HDEAD\RSET\TMO
WINBTS==RFCS\RFCR			; connection winning

; I/O channel definitions

ICP==0					; channel to get socket from logger
.U"NET==1				; channel to do real network hacking
.U"DAT==2				; channel to do data hacking

; Network numbers (for distinguishing IMP from local Ethernet)
.U"NT$NUM==:301400	;Byte pointer to network number (high 12 bits)
.U"NE%UNT==:040000,,0	;Escape bit indicating "Unternet" type address
.U"NE%STR==:100000,,0	;Escape bit indicating "string" type address
.U"NN%IP==:740000,,0	;host number bits that are off for all IP addresses
.U"NW%ARP==:<10.←24.>	;HOSTS3 uses full word network # values
.U"NW%MIL==:<26.←24.>	;LLL is on MILnet
.U"NW%SI==:<44←24.>	;Internet address of SU-NET-TEMP
.U"NW%SU==:<NE%UNT+NW%SI> ;"Unternet" used for Stanford Ethernet
;⊗ NWKDBG HSTADR HSTTOP HDBPTR DHSTST CONBLK CONSTS CONLSK CONWAT CONBYT ICPSKT CONFSK HOST CONHST LSNBLK LSNSTS LSNSKT LSNWAT LSNBYT LSNFSK LSNHST OPNBLK NETDEV

; Data area

NWKDBG:	0				; -1 → do OUTCHR on network I/O

IFN HSTTAB,[

; Host table pointers

.U"HSTADR:				; ≠ 0 → address of beginning of host table
	BLOCK 1				; = 0 → host table not in core
HSTTOP:	BLOCK 1				; top of host table (JOBFF at map time)
HDBPTR:	BLOCK 1				; pointer to relative HDB

; Block for ASCIZ text of dotted host number of host not in table
DHSTST:	BLOCK 10

]; End IFN HSTTAB

IFN TTYSTS,[

TTYFIL:	SIXBIT/TTYLOC/		;File of SU-Ethernet TTY location strings
	SIXBIT/TXT/
TTYPPN:	SIXBIT/HSTNET/
TIPFLG:	BLOCK 1			;Non-zero for Ethertips
TTYNAM:	BLOCK 10.		;Block to return TTY string

];End IFN TTYSTS

IFN NIORTS,[

; CONNECT MTAPE block

CONBLK:	0				; CONNECT
CONSTS:	BLOCK 1				; returned status bits
CONLSK:	BLOCK 1				; local socket
CONWAT:	BLOCK 1				; ≠ 0 → wait for connection until timeout
CONBYT:	BLOCK 1				; byte size
.U"ICPSKT:
CONFSK:	BLOCK 1				; foreign socket
.U"HOST:
CONHST:	BLOCK 1				; foreign host

IFN SVRRTS,[

; LISTEN MTAPE block

LSNBLK:	1				; LISTEN
LSNSTS:	BLOCK 1				; returned status bits
.U"LSNSKT:
	BLOCK 1				; local socket to listen to
LSNWAT:	BLOCK 1				; ≠ 0 → wait for connection
LSNBYT:	BLOCK 1				; byte size
LSNFSK:	BLOCK 1				; foreign socket
LSNHST:	BLOCK 1				; foreign host

]; End IFN SVRRTS

IFN NIORTS!SVRRTS,[
OPNBLK:	0
.U"NETDEV: 'IMP,,0			; device name
	 NTOBF,,NTIBF			; buffers
	
]; End IFN NIORTS!SVRRTS
;⊗ WATBLK WATSTS WATSKT INRBLK INRSTS INRSKT INSBLK INSSTS INSSKT ABTBLK ABTSTS WHYWHY NTIBF NTOBF DTIBF DTOBF RMKBLK RMKSTS RMKDAT FSOCKT LSOCKT

; More data area, shared by USER and SERVER

; WAIT MTAPE block

WATBLK:	4				; WAIT
WATSTS:	BLOCK 1				; returned status bits
WATSKT:	BLOCK 1				; socket number

; INTERRUPT MTAPE blocks

INRBLK:	11				; SEND INTERRUPT
INRSTS:	BLOCK 1				; returned status bits
INRSKT:	BLOCK 1				; socket number

INSBLK:	11
INSSTS:	BLOCK 1
INSSKT:	BLOCK 1

;ABORT MTAPE block

ABTBLK:	22			;ABORT
ABTSTS:	BLOCK 1			;Returned status bits

; Other stuff

WHYWHY:	BLOCK 1				; host down word

; I/O buffer headers

NTIBF:	BLOCK 3				; network input buffer header
NTOBF:	BLOCK 3				; network output buffer header

IFN DATRTS,[
DTIBF:	BLOCK 3				; network data input buffer header
DTOBF:	BLOCK 3				; network data output buffer header
]; End IFN DATRTS

IFN MRKCHR,[
RMKBLK:	26				; READ MARK
RMKSTS:	BLOCK 1
RMKDAT:	BLOCK 1				; mark byte returned here
]; End IFN MRKCHR

; Base sockets, set up by CONECT and LISTEN

.U"FSOCKT:
	BLOCK 1				; foreign base socket
.U"LSOCKT:
	BLOCK 1				; local base socket

]; End IFN NIORTS
;⊗ CONECT .CONEC

; CONECT -- Connect to foreign host
; Call:	MOVEM <host number>,HOST
;	MOVEM <ICP socket number>,ICPSKT
;	PUSHJ 17,CONECT
;	<error return--MTAPE lossage, status in 0> iff ERRHAN = 0
;	<error return--I/O error, status in 0> iff ERRHAN = 0
;	<return>
; Smashes 0 and 1.

IFN NIORTS,[

IFE SVRRTS,[

; Open channels and set timeouts

.U"CONECT:
IFN ERRHAN,[
	PUSHJ 17,.CONEC
	 JRST [PUSHJ 17,MTPERR ? ERRINS]
	 JRST [PUSHJ 17,NIOERR ? ERRINS]
	POPJ 17,
]; End IFN ERRHAN
.CONEC:	GETNET 0,HOST			; check network type
	MOVEI 1,'IMP			; Assume not PUP
	CAMN 0,[NW%SU]			; Ethernet?
	 MOVEI 1,'PUP			; Yes, use PUP
	MOVSM 1,NETDEV			; specify device for OPEN
	CAIN 1,'PUP
	 HRRZS HOST			; Don't confuse PUPSER with net number
	OPEN NET,OPNBLK			; open NET in ASCII mode
	 FATAL Network device INIT failure
	MTAPE NET,[17 ? CNTIMO]
	SETOM CONLSK			; gensym local socket
	SETOM CONWAT			; do wait until timeout
	MTAPE NET,CONBLK		; connect → foreign server
	MOVE CONLSK			; get gensymmed socket
	MOVEM LSOCKT			; save local base socket
	MOVE CONSTS			; get MTAPE status
	MOVEM WHYWHY			; save it
	GETSTS NET,			; check for I/O error on proper channel
	TRNE ERRBTS
	 JRST CPOPJ1
	MOVE WHYWHY
	TRNE 77				; check for MTAPE error
	 POPJ 17,
	TLC (WINBTS)			; for next instruction to win
	TLCE (WINBTS)			; legal socket state?
	 POPJ 17,
	MOVE CONFSK			; get socket we got
	MOVEM FSOCKT			; save foreign socket for later
	MOVE CONLSK			; for completeness and compatibilty
	MOVEM INSSKT
	MOVEI 8.			; change byte size in buffer header
	DPB [300600,,NTIBF+1]
	DPB [300600,,NTOBF+1]
	INBUF NET,
	OUTBUF NET,
	MTAPE NET,[17 ? TNTIMO]
	MTAPE NET,[10]
	 CAI
	JRST CPOPJ2

]; End IFE SVRRTS
;⊗ LISTEN .LISTE

; LISTEN -- Listen for an ICP from a foreign host
; Call:	MOVEM <ICP socket number>,LSNSKT
;	MOVEM <device name>,NETDEV	;If omitted, then use IMP
;	PUSHJ 17,LISTEN
;	<error return--MTAPE lossage, status in 0> iff ERRHAN = 0
;	<error return--I/O error, status in 0> iff ERRHAN = 0
;	<return--host we connected to in HOST>
; Smashes 0 and 1.

IFN SVRRTS,[

; Open channels and set timeouts (punts after a minute)

.U"LISTEN:
IFN ERRHAN,[
	PUSHJ 17,.LISTE
	 JRST [PUSHJ 17,MTPERR ? ERRINS]
	 JRST [PUSHJ 17,NIOERR ? ERRINS]
	POPJ 17,
]; End IFN ERRHAN
.LISTE:	OPEN NET,OPNBLK			; open NET in ASCII mode
	 FATAL Network device INIT failure
	MOVS 1,NETDEV
	MTAPE NET,[17 ? LSTIMO]
	SETOM LSNWAT			; do wait until timeout
	MTAPE NET,LSNBLK
	MOVE LSNSTS			; check for MTAPE error
	MOVEM WHYWHY
	TRNE 77
	 POPJ 17,
	GETSTS NET,			; check for I/O error
	TRNE ERRBTS
	 JRST CPOPJ1
	MOVE WHYWHY
	TLC (WINBTS)			; for next instruction to win
	TLCE (WINBTS)			; legal socket state?
	 POPJ 17,
	MOVE LSNHST
	MOVEM CONHST
	MOVE LSNFSK
	MOVEM FSOCKT			; save foreign base socket
	MOVE LSNSKT			; remember local socket
	MOVEM LSOCKT
	MOVEM INSSKT			; for completeness, set this as well
	MOVEI 8.			; change byte size in buffer header
	DPB [300600,,NTIBF+1]
	DPB [300600,,NTOBF+1]
	INBUF NET,
	OUTBUF NET,
	MTAPE NET,[17 ? TNTIMO]
	MTAPE NET,[10]
	 CAI
	JRST CPOPJ2

]; End IFN SVRRTS
;⊗ DATI .DATI .DATI1

; DATI -- Open data input network channel
; Call:	PUSHJ 17,DATI
;	<error return--MTAPE lossage, status in 0> iff ERRHAN = 0
;	<error return--I/O error, status in 0> iff ERRHAN = 0
;	<return--byte size in 0>
; Smashes 0 and 1.

IFN DATRTS,[

.U"DATI:
IFN ERRHAN,[
	PUSHJ 17,.DATI
	 JRST [PUSHJ 17,MTPERR ? ERRINS]
	 JRST [PUSHJ 17,NIOERR ? ERRINS]
	POPJ 17,
]; End IFN ERRHAN
.DATI:	CHNSTS DAT,			; check for channel open
	JUMPN .DATI1
	INIT DAT,0			; open channel
	 'IMP,,
	 DTOBF,,DTIBF			; buffers
	 FATAL IMP INIT failure
	MTAPE DAT,[17 ? DATIMO]
.DATI1:	MOVE LSOCKT
	ADDI 4				; ICP/U receive data offset
	MOVEM CONLSK			; local receive socket
	MOVE FSOCKT
	ADDI 3				; ICP/S transmit data offset
	MOVEM CONFSK			; foreign transmit socket
	SETOM CONWAT			; wait
	MTAPE DAT,CONBLK		; connect ← foreign data output
	MOVE CONSTS			; test for error
	MOVEM WHYWHY
	TRNE 77
	 POPJ 17,
	GETSTS DAT,
	TRNE ERRBTS
	 JRST CPOPJ1
	MOVE WHYWHY
	TLC (WINBTS)
	TLCE (WINBTS)
	 POPJ 17,
	MTAPE DAT,[15 ? 1]		; system maximum allocation
	MOVE CONBYT			; change byte size in buffer header
	DPB [300600,,DTIBF+1]
	INBUF DAT,
	MTAPE DAT,[10]
	 CAI
	JRST CPOPJ2
;⊗ DATO .DATO .DATO1

; DATO -- Open data output network channel
; Call:	MOVEI <byte size of connection>
;	PUSHJ 17,DATO
;	<error return--MTAPE lossage, status in 0> iff ERRHAN = 0
;	<error return--I/O error, status in 0> iff ERRHAN = 0
;	<return>
; Smashes 0 and 1.

.U"DATO:
IFN ERRHAN,[
	PUSHJ 17,.DATO
	 JRST [PUSHJ 17,MTPERR ? ERRINS]
	 JRST [PUSHJ 17,NIOERR ? ERRINS]
	POPJ 17,
]; End IFN ERRHAN
.DATO:	MOVEM CONBYT
	CHNSTS DAT,
	JUMPN .DATO1
	INIT DAT,0			; open channel
	 'IMP,,
	 DTOBF,,DTIBF			; buffers
	 FATAL IMP INIT failure
	MTAPE DAT,[17 ? DATIMO]
.DATO1:	MOVE LSOCKT
	ADDI 5				; ICP/U transmit data offset
	MOVEM CONLSK			; local receive socket
	MOVE FSOCKT
	ADDI 2				; ICP/S receive data offset
	MOVEM CONFSK			; foreign transmit socket
	SETOM CONWAT			; wait
	MTAPE DAT,CONBLK		; connect → foreign data input
	MOVE CONSTS			; test for error
	MOVEM WHYWHY
	TRNE 77
	 POPJ 17,
	GETSTS DAT,
	TRNE ERRBTS
	 JRST CPOPJ1
	MOVE WHYWHY
	TLC (WINBTS)
	TLCE (WINBTS)
	 POPJ 17,
	MOVE CONBYT			; change byte size in buffer header
	DPB [300600,,DTOBF+1]
	OUTBUF DAT,
	JRST CPOPJ2

]; End IFN DATRTS
;⊗ NETICH NETICW NTICH2 NTICH4 NTICH3

; NETICH/NETICW -- Read a character from the network
; Call:	PUSHJ 17,NETICH or PUSHJ 17,NETICW
;	<error return--I/O error, status in 0> iff ERRHAN = 0
;	<error return--no characters available> iff NETICH
;	<return--character in 0>
; Smashes 0, 1, and 2.

.U"NETICH:
	TDZA 2,2			; don't hang
.U"NETICW:
	 SETO 2,			; hang
IFN ERRHAN,[
	PUSHJ 17,NTICH2
	 JRST [PUSHJ 17,NIOERR ? ERRINS]
	 POPJ 17,			; NETICW or empty NETICH
	JRST CPOPJ1			; NETICH return
]; End IFN ERRHAN
NTICH2:	SOSLE NTIBF+2			; anything in buffer?
	 JRST NTICH3
	JUMPN 2,NTICH4
	HRRZ 1,NTIBF
	HRRZ 1,(1)
	SKIPGE (1)			; anything in further buffers?
	 JRST NTICH4
	MTAPE NET,[10]			; no, any input available?
	 JRST CPOPJ1			; no, empty error return
NTICH4:	IN NET,				; yes, read the buffer
	 JRST NTICH3			; won
	GETSTS NET,			; error, get status
IFN MRKCHR,[
	TRNN 0,IOBKTL			; mark seen?
]; End IFN MRKCHR
	POPJ 17,			; I/O error return
IFN MRKCHR,[
	MTAPE NET,RMKBLK		; read mark byte
	 POPJ 17,			; failed
	MOVE 0,RMKDAT
	TRO 0,400			; send it in specially marked package
	JRST CPOPJ2			; good return
]; End IFN MRKCHR
NTICH3:	ILDB NTIBF+1			; get the character
	SKIPE NWKDBG
	 OUTCHR
	JUMPN 2,CPOPJ1			; NETICW only skips once
	JRST CPOPJ2			; NETICH good return
;⊗ NETOCH .NETOC

; NETOCH -- Output a character to the network
; Call:	MOVE <character>
;	PUSHJ 17,NETOCH
;	<error return--I/O error, status in 0> iff ERRHAN = 0
;	<return>
; Smashes 0.

.U"NETOCH:
IFN ERRHAN,[
	PUSHJ 17,.NETOC
	 JRST [PUSHJ 17,NIOERR ? ERRINS]
	POPJ 17,
]; End IFN ERRHAN
.NETOC:	SOSG NTOBF+2			; space available in buffer?
	 OUT NET,			; no, output it
	  CAIA				; win
	   JRST NETOER
	IDPB NTOBF+1			; put character in buffer
	SKIPE NWKDBG
	 OUTCHR
	JRST CPOPJ1			; success
;⊗ NETSND .NETSN NETOER

; NETSND -- Force network buffer out
; Call:	PUSHJ 17,NETSND
;	<error return--I/O error, status in 0> iff ERRHAN = 0
;	<return>

.U"NETSND:
IFN ERRHAN,[
	PUSHJ 17,.NETSN
	 JRST [PUSHJ 17,NIOERR ? ERRINS]
	POPJ 17,
]; End IFN ERRHAN
.NETSN:	OUT NET,			; send the buffer
	 JRST [	AOS NTOBF+2		; poor NETOCH will lose big otherwise
		JRST CPOPJ1]
NETOER:	GETSTS NET,			; lost, get status
	POPJ 17,			; and return
;⊗ DATICH DATICW DTICH2 DTICH3 DTICH1 DTIC1A

; DATICH/DATICW -- Read a character from the network data channel
; Call:	PUSHJ 17,DATICH or PUSHJ 17,DATICW
;	<error return--I/O error, status in 0> iff ERRHAN = 0
;	<error return--no characters available> iff DATICH
;	<return--character in 0>
; Smashes 0, 1, and 2.

IFN DATRTS,[

.U"DATICH:
	TDZA 2,2			; don't hang
.U"DATICW:
	 SETO 2,			; hang
IFN ERRHAN,[
	PUSHJ 17,DTICH2
	 JRST [PUSHJ 17,NIOERR ? ERRINS]
	 POPJ 17,			; DATICW or empty DATICH
	JRST CPOPJ1			; DATICH return
]; End IFN ERRHAN
DTICH2:	SOSLE DTIBF+2			; anything in buffer?
	 JRST DTICH3
	JUMPE 2,[	HRRZ 1,DTIBF
			HRRZ 1,(1)
			SKIPGE (1)	; anything in further buffers?
			 JRST .+1
			MTAPE DAT,[10]	; no, any input available?
			 JRST CPOPJ1	; no, empty error return
			JRST .+1]	; input available or hang
	IN DAT,				; yes, read the buffer
	 JRST DTICH3			; won
	GETSTS DAT,			; error, get status
	POPJ 17,			; I/O error return
DTICH3:	LDB [300600,,DTIBF+1]		; get byte size
	CAIE 8.
	 JRST [	ILDB DTIBF+1		; non-ASCII data mode
		JUMPN 2,CPOPJ1
		JRST CPOPJ2]
	IBP DTIBF+1			; increment pointer to hack
	MOVE @DTIBF+1			; get word to hack
	ANDI 17 			; only marking bits
	JFFO DTICH1			; count leading zeros
	LDB DTIBF+1			; get the character
	JUMPN 2,CPOPJ1			; DATICW only skips once
	JRST CPOPJ2			; DATICH good return

; Have to flush nulls here.

DTICH1:	MOVNI 1,-44(1)			; get -1,,# of padding characters
	HRRZM 1,1(17)			; stash # of characters away on stack
	MOVEI 1,-1(1)			; # of characters to take off buffer
	SUBM 1,DTIBF+2			; remove padding characters from count
	MOVNS DTIBF+2			; SUBM goes the wrong way
	SKIPE 1				; maybe no adjustment necessary
DTIC1A:	IBP DTIBF+1
	SOJG 1,DTIC1A
	MOVN 1,1(17)			; get # of characters back from stack
	LSH 1,3				; # of bits to shift over
	MOVE @DTIBF+1			; get word we are hacking
	LSH (1)				; right justify its bytes
	MOVEM @DTIBF+1			; store it back again
	JRST DTICH2			; now try it again
;⊗ DATOCH .DATOC

; DATOCH -- Output a character to the network data channel
; Call:	MOVE <character>
;	PUSHJ 17,DATOCH
;	<error return--I/O error, status in 0> iff ERRHAN = 0
;	<return>
; Smashes 0.

.U"DATOCH:
IFN ERRHAN,[
	PUSHJ 17,.DATOC
	 JRST [PUSHJ 17,NIOERR ? ERRINS]
	POPJ 17,
]; End IFN ERRHAN
.DATOC:	SOSG DTOBF+2			; space available in buffer?
	 OUT DAT,			; no, output it
	  CAIA				; win
	   JRST DATOER
	IDPB DTOBF+1			; put character in buffer
	JRST CPOPJ1			; success
;⊗ DATSND .DATSN DATOER

; DATSND -- Force network buffer out
; Call:	PUSHJ 17,DATSND
;	<error return--I/O error, status in 0> iff ERRHAN = 0
;	<return>
; Smashes 0 and 1.

.U"DATSND:
IFN ERRHAN,[
	PUSHJ 17,.DATSN
	 JRST [PUSHJ 17,NIOERR ? ERRINS]
	POPJ 17,
]; End IFN ERRHAN
.DATSN:	LDB 1,[410300,,DTOBF+1]		; get position field
	MOVEI 1
	LSH (1)				; AC0 ← 2↑<# of null characters>
	SOS				; AC0 ← mask to flush nulls
	IORM @DTOBF+1			; ensure padding nulls aren't sent
	OUT DAT,			; send the buffer
	 JRST [	AOS DTOBF+2		; poor NETOCH will lose big otherwise
		JRST CPOPJ1]
DATOER:	GETSTS DAT,			; lost, get status
	POPJ 17,			; and return

]; End IFN DATRTS
;⊗ CLOSER CLSDAT

; CLOSER/CLSDAT -- Close a connection
; Call:	PUSHJ 17,CLOSER or PUSHJ 17,CLSDAT
;	<return>
; Smashes 0.

.U"CLOSER:
	CLOSE NET,
	RELEASE NET,
	TMSG [
Connection closed.
]
	POPJ 17,

IFN DATRTS,[

.U"CLSDAT:
	CLOSE DAT,
	RELEASE DAT,
	POPJ 17,

]; End IFN DATRTS
;⊗ NETINR NETINS ABORT

; NETINR/NETINS -- Send network interrupts to TELNET connection
; Call:	PUSHJ 17,NETINR (or NETINS)
;	<return>
; Smashes 0.

.U"NETINR:
	MTAPE NET,INRBLK		; interrupt from receiver
	POPJ 17,

.U"NETINS:
	MTAPE NET,INSBLK		; interrupt from sender
	POPJ 17,


; ABORT -- Abort TCP connection (send reset)
; Call:	PUSHJ 17,ABORT
;	<return>


.U"ABORT:
	MTAPE NET,ABTBLK
	POPJ 17,

]; End IFN NIORTS
;⊗ MTPERR MTPER1 MTPE1A MERTAB MERLEN

; MTPERR -- Explain MTAPE lossage
; Call:	MOVE <MTAPE status bits>
;	PUSHJ 17,MTPERR
;	<return>
; Smashes 0 and 1.

IFN ERRTNS,[

.U"MTPERR:
	TRNE 77				; UUO lossage?
	 JRST MTPER1			; yes, different message
	TLNN (CLSR)			; closed by foreign host?
	 SKIPA 1,[[ASCIZ/Time out
/]]
	  MOVEI 1,[ASCIZ/Refused
/]
	OUTSTR (1)
	CLRBFI
	POPJ 17,

; MTAPE UUO lossage

MTPER1:	ANDI 77				; only error code
	CAILE MERLEN			; error code too high?
	 JRST [	TMSG [MTAPE error #]
		IDIVI 10
		ADDI "0
		ADDI 1,"0
		OUTCHR
		OUTCHR 1
		JRST MTPE1A]
;;;	CAIN 0,15			;Is it the "host dead" code?
;;;	 JRST HSTDED			;Yes, say why
	MOVE 1,
	MOVE 1,MERTAB-1(1)		;Get word from table
	OUTSTR (1)			;Output the error string
	TLNN 1,600000			;Print crlf if not warning or fatal
	 TMSG [
]
	TLNE 1,400000			;Test for fatal error
	 JRST LUZBIG
	TLNE 1,200000			;Test for warning
MTPE1A:	 WARN
	CLRBFI
	POPJ 17,

;Bits in LH: 400000 if fatal error
;	     200000 if warning

MERTAB:	200000,,[ASCIZ/Socket in use/]
	200000,,[ASCIZ/Can't change socket/]
	200000,,[ASCIZ/System error/]		; horrible IMPSER bug; RTS&STR but no DDB
	[ASCIZ/No free links/]
	200000,,[ASCIZ/Illegal byte size/]
	[ASCIZ/IMP dead/]
	200000,,[ASCIZ/Gender mismatch/]	; the Anita Bryant feature
	;TOPS-10 error codes (from TCPSER.MAC[S,SYS]):
	200000,,[ASCIZ/State error/]				;(10)
	[ASCIZ/Can't get there from here/]			;(11)
	400000,,[ASCIZ/Not enough internal buffer space/]	;(12)
	[ASCIZ/Illegal host number/]				;(13)
	[ASCIZ/Destination net unreachable/]			;(14)
	[ASCIZ/Destination host unreachable/]			;(15)
	[ASCIZ/Destination protocol unreachable/]		;(16)
	[ASCIZ/Destination port unreachable/]			;(17)
	200000,,[ASCIZ/Fragmentation needed and DF set/]	;(20)
	200000,,[ASCIZ/Source route failed/]			;(21)
	200000,,[ASCIZ/Destination unreachable: unknown code/]	;(22)
MERLEN==.-MERTAB
;⊗ NIOERR

; NIOERR -- Explain network I/O lossage
; Call:	MOVE <I/O status bits>
;	PUSHJ 17,NIOERR
;	<return>
; Smashes 0, 1, and 2.

.U"NIOERR:
	ANDI ERRBTS			; only error bits
	SKIPN
	 FATAL No error status
	CLRBFI
	TRNE IOBKTL
	 FATAL Block too large
	TRNE IOIMPM
	 TMSG [Connection closed
]
	TRNE RSET
	 TMSG [Connection was reset
]
	TRNE TMO
	 TMSG [Time out
]
	TRNE IODEND
	 TMSG [Host closed connection
]
	TRNE HDEAD
	 JRST HSTDED
	POPJ 17,
;⊗ HSTDED

; HSTDED -- Explain why a host is dead

HSTDED:	LDB [260400,,WHYWHY]		; get what's wrong first
	JUMPE [	TMSG [Net trouble
]
		POPJ 17,]		; 0 → destination IMP down
	CAIE 1				; 1 → destination host down
	 JRST [	CAIN 2			; 2 → destination host talks 32 bit leaders
		 JRST [ TMSG [Communication with host not possible because it only talks 32 bit leaders
This probably indicates a hardware error at the other host, since 32-bit
leaders have been invalid since January 1, 1981.
]
			POPJ 17,]
ifn 0,[
		cain 17			; Funny code from CONECT for bad net?
		 JRST [	TMSG [Host net is inaccessible
]
			POPJ 17,]
];ifn 0
		TMSG [Communication prohibited!
]					; 3 → host access prohibited
		POPJ 17,]
	TMSG [Host dead, ]
	LDB 1,[220400,,WHYWHY]		; dead host status
	OUTSTR @(1)[	[ASCIZ/reason unknown/]
			[ASCIZ/system down/]
			[ASCIZ/foreign NCP down/]
			[ASCIZ/host doesn't exist/]
			[ASCIZ/NCP initialization/]
			[ASCIZ/scheduled PM/]
			[ASCIZ/hardware work/]
			[ASCIZ/software work/]
			[ASCIZ/emergency restart/]
			[ASCIZ/power failure/]
			[ASCIZ/software breakpoint/]
			[ASCIZ/hardware error/]
			[ASCIZ/scheduled down/]
			[ASCIZ/down code #13/]
			[ASCIZ/down code #14/]
			[ASCIZ/coming up now/]]
	TMSG [
]
;⊗ HSTDE2

; Hairy "when host up" code

	LDB [061400,,WHYWHY]		; get time when back up
	JUMPE CPOPJ
	CAIN 7776			; -2 → unknown future time
	 POPJ 17,
	TMSG [  Host is expected back up ]
	CAIN 7777			; -1 → more than a week
	 JRST [	TMSG [over a week from now.]
		POPJ 17,]
	LDB 1,[040500,,]		; 1.5→1.9 hours
	LDB 2,[110300,,]		; 2.1→2.3 day of week
	SUBI 1,8.			; PST/GMT offset
	MOVEI 3,261			; DAYLIT
	PEEK 3,
	PEEK 3,
	SKIPE 3
	 AOSL 1				; daylight losing time
	  JUMPGE 1,HSTDE2
	ADDI 1,24.			; hours become positive again
	SOJGE 2,HSTDE2			; back up a day
	MOVEI 2,6			; back to Monday
HSTDE2:	OUTSTR @(2)[	[ASCIZ/on Monday at /]
			[ASCIZ/on Tuesday at /]
			[ASCIZ/on Wednesday at /]
			[ASCIZ/on Thursday at /]
			[ASCIZ/on Friday at /]
			[ASCIZ/on Saturday at /]
			[ASCIZ/on Sunday at /]
			[ASCIZ/on April Fool's Day at /]]
	IDIVI 1,10.
	ADDI 1,"0
	OUTCHR 1
	ADDI 2,"0
	OUTCHR 2
	OUTCHR [":]
	LDB 1,[000400,,]		; 1.1→1.4 minutes/5
	IMULI 1,5.			; make into real minutes
	IDIVI 1,10.
	ADDI 1,"0
	OUTCHR 1
	ADDI 2,"0
	OUTCHR 2
	JUMPE 3,[	TMSG [ PST
]
			POPJ 17,]
	TMSG [ PDT
]
	POPJ 17,

]; End IFN ERRTNS
;⊗ HSTSID HSTFN1 HSTVRS HSTDIR HSTDEV HSTWHO HSTDAT HSTTIM NAMPTR SITPTR NETPTR NTNPTR HDRLEN NETNUM NTLNAM NTRTAB NETLEN ADDADR ADLSIT ADRCDR ADLXXX ADRSVC SVLCNT SVRCDR SVLFLG SVRNAM SVCARG ADDLEN STLNAM STRADR STLSYS STRMCH STLFLG STFSRV STFGWY SITLEN NMLSIT NMRNAM NAMLEN NNLNET NNRNAM NTNLEN HSTFIL HSTPPN

; Host table routines

IFN HSTTAB,[

; Herein is the description of the compiled binary file (HOSTS3.BIN).
; General terms:
;	"fileaddr" = a file address, relative to start of file.
;	"netaddr" = a network address, in HOSTS3 format.
;
; All strings (hostnames etc) are uppercase ASCIZ, word-aligned and
; fully zero-filled in the last word.  The strings are stored in the
; file in such a way that their locations are sorted, and only ONE
; copy of any distinct string is stored - everything that references
; the same string points to the same place.  Thus it is reasonable to
; compare string pointers for = as well as < and >, which is much
; faster than comparing the strings.

;The format of the compiled output file is:

HSTSID==:0	; wd 0	SIXBIT /HOSTS3/
HSTFN1==:1	; wd 1	SIXBIT FN1 of source file (eg HOSTS)
HSTVRS==:2	; wd 2	SIXBIT FN2 of source file (TNX: version #)
HSTDIR==:3	; wd 3  SIXBIT directory name of source file (eg SYSENG)
HSTDEV==:4	; wd 4  SIXBIT device name of source file (eg AI)
HSTWHO==:5	; wd 5	SIXBIT login name of person who compiled this
HSTDAT==:6	; wd 6  SIXBIT Date of compilation as YYMMDD
HSTTIM==:7	; wd 7	SIXBIT Time of compilation as HHMMSS
NAMPTR==:10	; wd 10 Fileaddress of NAME table.
SITPTR==:11	; wd 11	Fileaddress of SITE table.
NETPTR==:12	; wd 12 Fileaddress of NETWORK table.
NTNPTR==:13	; wd 13 Fileaddress of NETNAME table.
		;....expandable....
  HDRLEN==:14	; length of header

; NETWORK table
;	wd 0	Number of entries in table.
;	wd 1	Number of words per entry. (2)
; This table contains one entry for each known network.
; It is sorted by network number.
; Each entry contains:

NETNUM==:0	; wd 0 network number (full netaddr)
NTLNAM==:1	; wd 1 LH - fileaddr of ASCIZ name of network
NTRTAB==:1	; wd 1 RH - fileaddr of network's ADDRESS table
 NETLEN==:2

; ADDRESS table(s)
;	wd 0	Number of entries in table.
;	wd 1	Number of words per entry. (3)
; There is one of these tables for each network.  It contains entries
; for each site attached to that network, sorted by network address.
; These tables are used to convert a numeric address into a host name.
; Also, the list of network addresses and services for a site is stored
; within these tables.
; Each entry contains:

ADDADR==:0	; wd 0	Network address of this entry, in HOSTS3 fmt.
ADLSIT==:1	; wd 1 LH - fileaddr of SITE table entry
ADRCDR==:1	; wd 1 RH - fileaddr of next ADDRESS entry for this site
		;	 0 = end of list
ADLXXX==:2	; wd 2 LH - unused
ADRSVC==:2	; wd 2 RH - fileaddr of services list for this address
		;	0 = none, else points to SERVICE node of format:
	SVLCNT==:0	;		<# wds>,,<fileaddr of next, or 0>
	SVRCDR==:0
	SVLFLG==:1	;		<flags>,,<fileaddr of svc name>
	SVRNAM==:1
	SVCARG==:2	;		<param1> ? <param2> ? ...
 ADDLEN==:3

; SITE table
;	wd 0	Number of entries in table.
;	wd 1	Number of words per entry. (3)
; This table contains entries for each network site,
; not sorted by anything in particular. A site can have more
; than one network address, usually on different networks.
; This is the main, central table.
; Each entry looks like:

STLNAM==:0	; wd 0 LH - fileaddr of official host name
STRADR==:0	; wd 0 RH - fileaddr of first ADDRESS table entry for this
		;		site.  Successive entries are threaded
		;		together through ADRCDR.
STLSYS==:1	; wd 1 LH - fileaddr of system name (ITS, TIP, TENEX, etc.)
		;		May be 0 => not known.
STRMCH==:1	; wd 1 RH - fileaddr of machine name (PDP10, etc.)
		;		May be 0 => not known.
STLFLG==:2	; wd 2 LH - flags:
STFSRV==:400000	;	4.9 1 => server site (has FTP or TELNET)
STFGWY==:200000	;	4.8 1 => Internet Gateway site (HOSTS3 only)
 SITLEN==:3

; NAMES table:
;	wd 0	Number of entries
;	wd 1	Number of words per entry. (1)
; This table is used to convert host names into network addresses.  It
; contains entries sorted alphabetically by host name.

NMLSIT==:0	; wd 0 LH - fileaddr of SITE table entry for this host.
NMRNAM==:0	; wd 0 RH - fileaddr of host name
		; This name is official if NMRNAM = STLNAM of NMLSIT.
 NAMLEN==:1

; NETNAME table:
;	wd 0	Number of entries
;	wd 1	Number of words per entry. (1)
; This table is used to convert network names into network numbers.  It
; contains entries sorted alphabetically by network name, exactly as
; for the NAMES table.  Although the symbols below are different (in order
; to make semantic distinctions), programs can depend on the fact
; that the NETNAME table format is identical to that of the NAMES table.

NNLNET==:0	; wd 0 LH - fileaddr of NETWORK table entry for this host.
NNRNAM==:0	; wd 0 RH - fileaddr of network name
 NTNLEN==:1

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;		HOSTS3 Network Address Format           ;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

comment |
HOSTS3 network address format:

   4.9-4.6 - 4 bits of format type, which specify interpretation of
		the remaining 32 bits.
IN	0000 - Internet address (handles ARPA, RCC, LCS)
		4.5-1.1 - 32 bits of IN address.
UN	0001 - Unternet address.  Same format, but not part of Internet.
		4.5-3.7 - HOSTS3-defined network number (1st 8-bit byte)
		3.6-1.1 - address value in next 24 bits.
			This handles CHAOS and any local nets.  The network
			numbers are unique within the HOSTS3 table but
			don't necessarily mean anything globally, as do
			Internet network numbers.
	0011 - String address.
		4.5-3.7 - HOSTS3-defined network number (1st 8-bit byte)
		3.6-3.1 - 0
		2.9-1.1 - address of ASCIZ string in file/process space

Note that the "network number" for all of these formats is located in
the same place.  However, for fast deciphering of the entire range of
possibilities, one could simply consider all of the high 12 bits as the
network number.  Beware of the Internet class A, B, and C formats, though;
the only truly general way to compare network numbers is to use their
masked 36-bit values, although simpler checks are OK for specific nets.
For this reason (among others) network numbers are represented by
full 36-bit values with the "local address" portion zero.

The 4-bit "String address" value is much more tentative than the IN or UN
values.  Bit 4.9, the sign bit, is being reserved as usual for the possible
advent of a truly spectacular incompatible format.
|

HSTFIL:	SIXBIT/HOSTS3/		;filename and extension of binary file
	SIXBIT/BIN/
HSTPPN:	SIXBIT/HSTNET/		;PPN of binary file
;⊗ MAPHST

; MAPHST -- Map host table into core
; Call:	PUSHJ 17,MAPHST
;	<return>
; Smashes 0, 1, 2, and 3.

.U"MAPHST:
	SKIPE HSTADR
	 JRST [	WARN Host table already mapped
		POPJ 17,]
	INIT 17
	 'DSK,,
	 0
	 FATAL DSK INIT failure
	DMOVE HSTFIL			; get filename and extension
	MOVE 3,HSTPPN			; get PPN
	LOOKUP
	 JRST [	TMSG [Host table LOOKUP failure (]
		ANDI 1,77
		IDIVI 1,10
		ADDI 1,"0 ? ADDI 2,"0
		OUTCHR 1 ? OUTCHR 2 ? OUTCHR [")]
		JRST LUZBIG]
	MOVE 2,JOBFF
	MOVS 3 ? MOVN ? ADDB JOBFF	; get address of highest addr we need
	MOVEM HSTTOP
	CORE				; get more core from system maybe
	 FATAL CORE UUO failure
	MOVE 3 ? HRRI -1(2)		; compute IOWD to read host table in
	SETZ 1,
	INPUT
	MOVE (2)			; get first word of host table
	CAME HSTFIL
	 FATAL Bad host table
	MOVEM 2,HSTADR			; remember where host table begins
	RELEAS
	POPJ 17,
;⊗ UNMHST

; UNMHST -- Unmap host table from core
; Call:	PUSHJ 17,UNMHST
;	<return>
; Smashes 0 and 1.

.U"UNMHST:
	SKIPN 1,HSTADR			; host table in core?
	 JRST [	WARN Host table not mapped
		POPJ 17,]
	MOVE (1)
	CAME HSTFIL
	 FATAL Bad host table
	MOVE HSTTOP			; check JOBFF from before
	CAMLE JOBFF			; smashed too?
	 FATAL Host table after JOBFF
	CAME JOBFF
	 JRST [	WARN Host table locked
		POPJ 17,]
	SETZM HSTADR			; remove table pointer/interlock
	MOVEM 1,JOBFF			; return host table to free storage
	CORE 1,				; and garbage collect
	 FATAL CORE UUO failure
	POPJ 17,
;⊗ HSTNUM HSTNUS HSTNU1 HSTNU2

; HSTNUM -- Return descriptor block for a host
; Call:	MOVEI <host number>
;	PUSHJ 17,HSTNUM
;	<error return--no such host>
;	<return--absolute NAMNUM in 0, NUMSYS,,NUMNAM in 1, NUMBTS,,NUMMCH in 2,
;	 address block in 3>
; Smashes 0, 1, 2, 3, and 4.

.U"HSTNUM:
	SKIPN 1,HSTADR			; fail if host table not mapped
	 FATAL Host table not mapped
	MOVE 2,(1)
	CAME 2,HSTFIL
	 FATAL Bad host table
	GETNET 4,0			; get network number
	MOVE 1,NETPTR(1)
	PUSHJ 17,HSTNUS			; lookup network number
	  POPJ 17,
	MOVE 1,NTRTAB(1)		; get address table for network
	MOVEM 4				; thing to search for
	PUSHJ 17,HSTNUS			; lookup address
	  POPJ 17,
	MOVE 3,1			; Save address table entry
	HLRZ 1,ADLSIT(1)		; Get site table entry
	ADD 1,HSTADR
	AOS (17)			; successful return
	JRST GETHDB			; return useful stuff in ACs

HSTNUS:	ADD 1,HSTADR			; relocate table
	MOVE 2,(1)			; get # of entries
	MOVE 3,1(1)			; and entry size
	ADDI 1,2			; point at first entry
HSTNU1:	CAMN 4,(1)			; found it?
	  JRST CPOPJ1			;   yes, skip return for success
	ADD 1,3				; point at next entry
	SOJG 2,HSTNU1			; keep on searching
;Special treatment for failed search on SU-NET hosts, to look up name using
;SU-ETHERNET (PUP) host number.  Note that this code depends on knowing the
;format of SU-Net host numbers (currently class A).  Hopefully this code can
;disappear someday, when our host table contains the IP numbers of these hosts.
	TDZ 4,[77,,-1]		;Get class-A host number
	CAME 4,[NW%SI]		;SU-Net?
	 JRST HSTNU2		;No
	PUSH 17,0		;Save original (IP) host number
	LDB 4,[201000,,0]	;Get subnet from bits 12-19
	DPB 4,[102000,,0]	;Store in bits 20-27, clear 12-19
	TLC 0,(NW%SI#NW%SU)	;Change net number
	PUSHJ 17,HSTNUM		;Call ourself!
	 JRST [	POP 17,0	;Still failed.  Oh well.
		JRST HSTNU2]	;Make ASCIZ string for IP host number
	POP 17,0		;Get back IP host number
	POP 17,(17)		;Avoid going to GETHDB again
	JRST CPOPJ1		;Skip return to caller of HSTNUM

;Here if host not in our host table.  Generate ASCIZ string for host number
;instead of name.
HSTNU2:	MOVEI 1,DHSTST		;Address for ASCIZ host number string
	PUSHJ 17,HNUMST		;Preserves 1
	SETZM HDBPTR		;no HDB
	SETZB 2,3
	POPJ 17,		;failure return
;⊗ HSTNAM CNTCHR HSTNAB HSTNB1 HSTNB2 HSTNB3 HSTNB4 HSTNB5 HSTUNK HSTUN1

; HSTNAM -- Return descriptor block for a host name
; Call:	MOVEI <pointer to host name string>
;	PUSHJ 17,HSTNAM
;	<error return--no such host>
;	<error return--ambiguous name>
;	<return--absolute NAMNUM in 0, NUMSYS,,NUMNAM in 1, NUMBTS,,NUMMCH in 2,
;	 address block in 3>
; Smashes 0 → 10 (!!!).

.U"HSTNAM:
	SKIPN 1,HSTADR			; fail if host table not mapped
	 FATAL Host table not mapped
	MOVE 2,(1)
	CAME 2,HSTFIL
	 FATAL Bad host table

;  Set up various AC's for hairy search below.  0 has a pointer to the input
; host, 1 has the host table pointer, 2 has the character count.

	MOVE 3,0
	HRLI 3,440700			; make byte pointer
	MOVE 4,3
	ILDB 2,4			; Get first char
	CAIN 2,"[
	 JRST HSTNAB			; Parse bracketd host number
	MOVE 2,NAMPTR(1)
	ADD 2,HSTADR			; address of NAMES table
	HRLO 1,(2)			; # of entries,,-1
	EQVI 1,1(2)			; -<1+# of entries>,,table-1
	ADJSP 1,1			; now have AOJBN pointer to table
	SETZ 2,				; character count

; Compute character count in AC 2

CNTCHR:	ILDB 4,3
	JUMPE 4,[	JUMPE 2,CPOPJ	; null specification loses
			SETZB 3,4	; init pointers
			JRST SEARCH]
	CAIL 4,"a			; lowercase?
	 SUBI 4,"a-"A
	DPB 4,3
	AOJA 2,CNTCHR

; Parse a bracketed specification of the form [a.b.c.d]

HSTNAB:	SETZ 0,			;0 will hold result
	MOVEI 1,4		;Number of components
HSTNB1:	SETZ 2,			;Current component
HSTNB2:	ILDB 3,4		;Get next char
	CAIL 3,"0
	CAILE 3,"9
	 JRST HSTNB3		;Non-numeric
	IMULI 2,10.
	ADDI 2,-"0(3)
	JRST HSTNB2

HSTNB3:	CAILE 2,255.		;Legal?
	 POPJ 17,		;No, lose
	LSH 0,10
	ADDI 0,(2)
	SOJLE 1,HSTNB4		;Count components
	CAIE 3,".		;Looking for delimiter
	 POPJ 17,		;Bad format
	JRST HSTNB1		;Keep going

HSTNB4:	JUMPE 3,HSTNB5		;Allow omission of final delimiter
	CAIE 3,"]		;Last delimiter is different
	 POPJ 17,
	ILDB 3,4		;Check for garbage at end
	JUMPN 3,CPOPJ
HSTNB5:	PUSH 17,0
	PUSHJ 17,HSTNUM		;Look it up if we can
	 DMOVE 1,HSTUN1		;Not in table - use dummy data
	POP 17,0
	JRST CPOPJ2

HSTUNK:	ASCIZ/unknown/
HSTUN1:	HSTUNK,,HSTUNK
	0,,HSTUNK
;⊗ SEARCH SRCNXW SRCWIN SRCLUZ SRCDUN GOTNAM AMBNAM GETHDB

; Host name search

SEARCH:	MOVEI 5,(2)			; copy of count
	MOVE 6,				; copy of source pointer
	HRRZ 7,(1)
	ADD 7,HSTADR			; pointer for this entry
SRCNXW:	MOVE 10,(7)
	MOVE 11,(6)
	ANDCMI 11,1			; 1.1 is a loser
	CAIL 5,5.			; account for this word
	 JRST [	CAME 10,11		; match for this word?
		 JRST SRCLUZ
		SUBI 5,5.		; match, account for this word
		ADDI 7,1
		AOJA 6,SRCNXW]		; still more to go
	AND 11,[.BYTE 7 ? 177 ? 000 ? 000 ? 000 ? 000
		.BYTE 7 ? 177 ? 000 ? 000 ? 000 ? 000
		.BYTE 7 ? 177 ? 177 ? 000 ? 000 ? 000
		.BYTE 7 ? 177 ? 177 ? 177 ? 000 ? 000
		.BYTE 7 ? 177 ? 177 ? 177 ? 177 ? 000](5)
	CAMN 10,11			; exact match?
	 JRST [	HLRZ 1,(1) ? ADD 1,HSTADR
		JRST GOTNAM]		; stop the presses!
	SOJL 5,SRCWIN			; this string ends on word boundry
	AND 10,[.BYTE 7 ? 177 ? 000 ? 000 ? 000 ? 000
		.BYTE 7 ? 177 ? 177 ? 000 ? 000 ? 000
		.BYTE 7 ? 177 ? 177 ? 177 ? 000 ? 000
		.BYTE 7 ? 177 ? 177 ? 177 ? 177 ? 000](5)
	CAME 10,11			; match for partial word?
	 JRST SRCLUZ
SRCWIN:	HLRZ 5,(1) ? ADD 5,HSTADR	; set up pointer to HDB
	MOVE 6,2(5)			; NUMBTS
	TLNE 6,STFSRV			; server?
	 JRST [	CAMN 3,5		; all self-matches win
		 JRST SRCLUZ
		SKIPE 3			; somebody there?
		 TLOA 3,-1		; yah, loser
		  MOVE 3,5		; else remember the name
		AOBJN 1,SEARCH		; keep on hunting
		JRST SRCDUN]		; else done
	CAMN 4,5			; self-matcher?
	 JRST SRCLUZ
	SKIPE 4				; already seen a user?
	 TLOA 4,-1			; remember can't be a user
	  MOVE 4,5			; else remember the pointer
SRCLUZ:	AOBJN 1,SEARCH			; maybe could be a server in there

; Search done, set up HDB ala HSTNUM and return

SRCDUN:	SKIPN 1,3			; use server if found one
	 MOVE 1,4			; no server, maybe a user
	JUMPE 1,CPOPJ			; no match at all
	SKIPL 1				; ambiguous name?
GOTNAM:	 AOS (17)			; no, set up double skip return
AMBNAM:	AOS (17)			; ordinary skip return

; Routine to get a block of host specifications with pointer in 1.

	HRRZ 3,STRADR(1)		; get address block
	ADD 3,HSTADR
	MOVE ADDADR(3)			; host number
GETHDB:	MOVE 2,STRMCH(1)		; NUMBTS,,NUMMCH
	HLL 2,STLFLG(1)
	TRNE 2,-1
	 ADD 2,HSTADR
	MOVEM 1,HDBPTR			; save pointer to HDB
	SUB 1,HSTADR
	EXCH 1,HDBPTR
	HLL 1,STLSYS(1)
	HLR 1,STLNAM(1)			; NUMSYS,,NUMNAM
	TLNN 1,-1
	 JRST [	ADD 1,HSTADR		; case of unknown system name
		POPJ 17,]
	ADJSP 1,@HSTADR
	POPJ 17,			; and return
;⊗ HSTNXA

; HSTNXA -- Return descriptor block for a host
; Call:	MOVE 3,<number return by HSTNAM as address block>
;	PUSHJ 17,HSTNXA
;	<error return--no other addresses>
;	<return--absolute NAMNUM in 0, next address block in 3>
; Does not disturb 1,2

.U"HSTNXA:
	SKIPN HSTADR			; fail if host table not mapped
	 FATAL Host table not mapped
	MOVE 0,@HSTADR
	CAME 0,HSTFIL
	 FATAL Bad host table
	HRRZ 3,ADRCDR(3)		; get other address(es), if any
	JUMPE 3,[ SETZ 0,		; if no addresses left, fail
		  POPJ 17,]
	ADD 3,HSTADR
	MOVE 0,ADDADR(3)		; get this address
	AOS (17)
	POPJ 17,			; failure
;⊗ SVCCHK SVCCH1 SVCCH2 SVCCH3

;SVCCHK -- Check address block for a specific service.
;Call:	MOVE 3,<number returned by HSTNUM, HSTNAM, or HSTNXA as address block>
;	MOVEI 1,[ASCIZ/string to match/]
;	PUSHJ 17,SVCCHK
;	<return if string not in service list>
;	<return if string in service list>
;Preserves 0-3.  Smashes 4-10.

.U"SVCCHK:
	SKIPN HSTADR		;Fail if host table not mapped
	 FATAL Host table not mapped
	HRRZ 4,ADRSVC(3)	;Address of services list
SVCCH1:	JUMPE 4,CPOPJ		;No services, or end of list
	ADD 4,HSTADR
	HRRZ 5,SVRNAM(4)	;Get name of service
	ADD 5,HSTADR
	HRLI 5,440700		;Set up byte pointers
	MOVSI 6,440701
SVCCH2:	ILDB 7,5
	ILDB 10,6
	JUMPE 7,[JUMPE 10,CPOPJ1 ;Succeed if simultaneous end
		JRST SVCCH3]	;Try next if one ends early
	JUMPE 10,SVCCH3
	CAMN 7,10
	 JRST SVCCH2		;Match, keep checking
SVCCH3:	HRRZ 4,SVRCDR(4)	;Get next service node
	JRST SVCCH1
;⊗ SETANM SETA00 SETAN1 SETAN0 SETAN2 SETAN4 SETAN5 SETAN9 SETAN6 SETAN7 SETAN8

; SETANM -- Generate alias name from host name
; Call:	<call to HSTNUM or HSTNAM to set up HDB pointer>
;	PUSHJ 17,SETANM
; Smashes 0 → 7 (!!!).

IFN HSTSIX,[

.U"SETANM:
	HRRZ 6,1			; check official name first
	SKIPN 1,HDBPTR
	 JRST SETA00			; no host was found, use dotted host nbr
	MOVE 2,HSTADR
	HRRZ 2,NAMPTR(2)		; get address of NAMES table.
	ADD 2,HSTADR
	SKIPA 3,(2)			; number of entries in the table.
SETA00:	MOVEI 3,0			; no match earlier, don't look again
	SETOB 4,5			; 4 ← longest name ≤ 6 chars, 5 ← length
	AOJA 2,SETAN0			; skip word 1 of table (entry length)

SETAN1:	ADDI 2,1			; next untried NAMES table entry.
	HLRZ 6,(2)
	CAME 6,1			; name the host we are serving?
	 JRST SETAN4
	HRRZ 6,(2)			; how long is this name?
	ADD 6,HSTADR
SETAN0:	HRLI 6,440700
	PUSH 17,6
	PUSH 17,6
	SETZ 7,
SETAN2:	ILDB 6,(17)
	SKIPE 6
	 AOJA 7,SETAN2

	POP 17,6			; flush garbage
	POP 17,6			; restore pointer to name
	CAIG 7,6			; fit in 6 characters?
	 CAMG 7,4			; and longer than the previous one?
	  JRST SETAN4
	HRRZ 5,6			; save name's address
	MOVE 4,7			; and the length
SETAN4:	SOJG 3,SETAN1			; look through the rest of the table.
	JUMPGE 4,SETAN5			; jump if found a reasonable name
	MOVEI 4,"-			; also, will remove hyphens from it
	SKIPN 5,HDBPTR
	JRST SETAN9			; no host name at all, using dotted nbr
	ADD 5,HSTADR			; no short name, truncate official one
	HLRZ 5,STLNAM(5)
	ADD 5,HSTADR			; pointer to name
SETAN5:	SKIPA 2,5
SETAN9:	MOVEI 2,(6)			; ptr to dotted host number string
	HRLI 2,440700			; get BP to name string.
	MOVSI 1,440600
	SETZ 0,				; convert name to SIXBIT word in 0
SETAN6:	ILDB 3,2
	JUMPE 3,SETAN7			; stop if name string runs out
	CAMN 3,4			; remove hyphens if requested to
	 JRST SETAN6			; note 4 has number from 1 to 6 or "-
	SUBI 3,<" >-<' >
	IDPB 3,1
	TLNE 1,770000			; stop after getting one full word.
	 JRST SETAN6
SETAN7:	LDB 3,1				; if last character is a hyphen, flush it.
	CAIN 3,'-
	 SETZ 3,
	DPB 3,1
SETAN8:	TRNN 0,-1			; if right half of "alias" is zero,
	 IORI '.			;   then add a dot to make it "longer"
	SETO 1,
	GETLIN 1
	AOSN 1				; don't screw DSK PPN if not a phantom
	 DSKPPN
	POPJ 17,

]; End IFN HSTSIX
;⊗ HNUMST HNUMS2 HNUMS4 HNUMS5 HNUMSD HNUMSO HNUMS6

;HNUMST -- Generate text string from host number
;Call:	MOVE 0,<host number>
;	MOVE 1,<address to store text string, or IDPB pointer>
;	PUSHJ 17,HNUMST
;Assumes enough space for string and final null byte.  (Currently at most 16.
;characters.)  Smashes 2, 3, and 4 (preserves 0 and 1).

.U"HNUMST:
	PUSH 17,1		;Save address
	TLNN 1,-1		;Byte ptr in 1?
	HRLI 1,440700		;No, make one
	JUMPE 0,HNUMS4		;Return blank string for 0
	GETNET 4,0		;Get network number
	CAMN 4,[NW%SU]		;Is it the Ethernet?
	JRST HNUMS5		;Yes, generate subnet#host
	PUSH 17,[401000,,0]	;byte ptr to ILDB for host number
	SKIPA 2,["[]		;start with a bracket
HNUMS2:	MOVEI 2,".		;insert dot between parts of host number
	IDPB 2,1		;stuff into host "name" string (actually host nbr)
	ILDB 2,(17)		;get next byte of host nbr
	PUSHJ 17,HNUMSD		;convert to decimal string
	MOVE 2,(17)
	TLNE 2,770000		;end of word in byte ptr?
	JRST HNUMS2		;no, output more parts of host nbr
	ADJSP 17,-1		;flush byte ptr from stack
	MOVEI 2,"]"		;end with a bracket
	IDPB 2,1
HNUMS4:	MOVEI 2,0		;terminate host string with a null
	IDPB 2,1
	POP 17,1		;Restore original addr
	POPJ 17,

HNUMS5:	LDB 2,[101000,,0]	;Get subnet number
	PUSHJ 17,HNUMSO		;Convert to octal string
	MOVEI 2,"#		;Insert delimiter
	IDPB 2,1
	LDB 2,[001000,,0]	;Get host number
	PUSHJ 17,HNUMSO		;Put in host number string
	JRST HNUMS4		;Finish up

HNUMSD:	SKIPA 4,[10.]		;Usual decimal output routine
HNUMSO:	MOVEI 4,10		;Octal output
HNUMS6:	IDIV 2,4
	HRLM 3,(17)
	JUMPE 2,.+2
	PUSHJ 17,HNUMS6
	HLRZ 3,(17)
	ADDI 3,"0
	IDPB 3,1		;Stick digit into host string
	POPJ 17,
;⊗ OURNAM OURNA1

;OURNAM -- Get our host name
;Call:	PUSHJ 17,OURNAM
;	<error return--can't get our name>
;	<return--absolute NAMNUM in 0, NUMSYS,,NUMNAM in 1, NUMBTS,,NUMMCH in 2,
;	 address block in 3>
; Smashes 0, 1, 2, 3, and 4.

.U"OURNAM:
	MOVEI 1,355		;Lowcore ptr to table of host numbers
	PEEK 1,			;Get AOBJN ptr
	JUMPGE 1,CPOPJ
	;Loop thru system table until we find a name
OURNA1:	HRRZ 0,1		;System address of next name in table
	PEEK 0,			;Get host number
	PUSH 17,1		;Save AOBJN ptr
	PUSHJ 17,HSTNUM
	 JRST [	POP 17,1	;Failed
		AOBJN 1,OURNA1	;Try next number
		POPJ 17,]	;Lose if we tried them all
	POP 17,(17)		;Flush AOBJN ptr
	JRST CPOPJ1

]; End IFN HSTTAB
;⊗ TTYSTR TTYST1 TTST1A TTYST2 TTST2A TTYST3 TTYST4 TTST4A TTYST5 TTST5A TTST5B TTYST6 TTYST9

;TTYSTR -- Get TTY location string for SU-Ethernet host
;Call:	MOVE 1,<address of ASCIZ string containing host name>
;	MOVE 2,<port number for Ethertips, else -1>
;	PUSHJ 17,TTYSTR
;	 <error return - not in table>
;	<success, byte ptr to TTY location string in 1>
;Smashes 0-4.  Temporarily uses core above JOBFF, and I/O channel 0.

IFN TTYSTS,[

.U"TTYSTR:
	MOVE 3,(1)		;Get first word of host name
	TRZ 3,377		;Get just 4 chars
	SETZM TIPFLG		;Assume not an Ethertip
	CAME 3,[ASCII/TIP-/]	;Being generous, we recognize two forms
	CAMN 3,[ASCII/Tip-/]
	SETOM TIPFLG		;This is an Ethertip
	HRLI 1,440700		;Make byte ptr
	PUSH 17,1		;Save arguments
	PUSH 17,2
	INIT 17
	 'DSK,,
	 0
	 FATAL DSK INIT failure
	DMOVE 0,TTYFIL
	MOVE 3,TTYPPN
	LOOKUP
	 JRST TTYST9		;Return quietly if file not there
	MOVE 2,JOBFF
	MOVS 3 ? MOVN ? ADD JOBFF ;Get address of highest addr we need
	CORE			;Get more core from system maybe
	 FATAL CORE UUO failure
	MOVE 3 ? HRRI -1(2)	;Compute IOWD to read host table in
	SETZ 1,
	INPUT
	HRLI 2,440700		;Byte ptr to data read in
;Begin next line in file
TTYST1:	MOVE 0,2		;Remember position
	MOVE 1,-1(17)		;Get byte ptr to name to match
TTST1A:	ILDB 3,1		;Char from string to match
	ILDB 4,2		;Char from file
	JUMPE 3,TTYST3		;Jump at end of string
	JUMPE 4,TTYST9		;Jump at end of file
	CAIN 4,12		;End of line?
	JRST TTYST1		;Yes, start a new one
	CAIL 3,"a		;Upper casify both chars
	SUBI 3,"a-"A
	CAIL 4,"a
	SUBI 4,"a-"A
	CAMN 3,4		;Match?
	JRST TTST1A		;Yes, keep looking
TTYST2:	ILDB 4,2		;No, skip to end of line or file
TTST2A:	JUMPE 4,TTYST9
	CAIN 4,12
	JRST TTYST1
	JRST TTYST2

TTYST3:	CAIN 4,"#		;Port number in file?
	JRST TTYST5		;Yes, go see if match
	CAIE 4,":		;End of host name?
	JRST TTYST2		;No
TTYST4:	MOVE 1,[440700,,TTYNAM]	;Set up ptr to copy name
	MOVE 2,0		;Get saved start of TTY string
	SKIPN TIPFLG		;Was this an Ethertip?
	JRST TTST4A		;No, just copy string
	IBP 2			;Yes, I know about ADJBP but this might
	IBP 2			;someday want to work on a Foonly
	IBP 2
	IBP 2			;Now we've skipped "Tip-" in the string
TTST4A:	ILDB 0,2		;Copy chars to end of line
	CAIN 0,15
	JRST TTYST6		;End of line in file
	IDPB 0,1
	JRST TTST4A

TTYST5:	MOVEI 3,0		;Compute port number in 3
TTST5A:	ILDB 4,2		;Get a char
	CAIN 4,":		;End of port number?
	JRST TTST5B
	CAIL 4,"0		;Check for digit
	CAILE 4,"7
	JRST TTST2A		;I'm confused.  Skip this line
	LSH 3,3			;Multiply by 8 (numbers in file are octal)
	ADDI 3,-"0(4)
	JRST TTST5A

TTST5B:	CAME 3,(17)		;Is it the right port?
	JRST TTYST2		;I'm afraid not
	JRST TTYST4		;Yes, we win

TTYST6:	MOVEI 0,0		;End with a null
	IDPB 0,1
	MOVE 0,JOBFF		;Garbage collect
	CORE
	 FATAL CORE UUO failure
	AOS -2(17)		;Set skip return
	MOVE 1,[440700,,TTYNAM]	;Set return value
TTYST9:	RELEAS			;Give up I/O channel
	ADJSP 17,-2		;Flush arguments
	POPJ 17,

];End IFN TTYSTS
;⊗ CPOPJ2 CPOPJ1 CPOPJ WARNIN LUZBIG ..NLIT

; All good things must come to an end

; Return routines

CPOPJ2:	AOS (17)			; double skip return
CPOPJ1:	AOS (17)			; skip return
CPOPJ:	POPJ 17,			; return to caller

; Warning

.U"WARNIN:
	TMSG [
Please report this via GRIPE NETWORK.
]
	POPJ 17,

; Fatality!

.U"LUZBIG:
	TMSG [
Find a wizard.
]
	JRST 4,WARNIN

..NLIT:	CONSTANTS

.END NETWRK